Function f_julidat2gregdat(pin_jldat As Double) As Date
'Heiko Hommes
'08.09.2008
'Berechnet aus einem modifiziertem julianischen Datum ein gregorianisches Datum
'also aus 1223123123 kommt 01.01.2006 <= ist nur ein Beispiel

Dim vn_jahr    As Double
Dim vn_monat   As Double
Dim vn_tag     As Double
Dim vn_stunde  As Double
Dim vn_minute  As Double
Dim vn_sekunde As Double
Dim vn_jd      As Double
Dim vn_jd0     As Double
Dim vn_b       As Double
Dim vn_c       As Double
Dim vn_d       As Double
Dim vn_e       As Double
Dim vn_f       As Double

vn_jd = pin_jldat + 2400000.5
vn_jd0 = Int(vn_jd + 0.5)

If (vn_jd0 < 2299161) Then
    
    vn_c = vn_jd0 + 1524

Else
    
    vn_b = Int((vn_jd0 - 1867216.25) / 36524.25)
    vn_c = vn_jd0 + (vn_b - Int(vn_b / 4)) + 1525

End If

vn_d = Int((vn_c - 122.1) / 365.25)
vn_e = 365 * vn_d + Int(vn_d / 4)
vn_f = Int((vn_c - vn_e) / 30.6001)

vn_tag = Int(vn_c - vn_e + 0.5) - Int(30.6001 * vn_f)
vn_monat = vn_f - 1 - 12 * Int(vn_f / 14)
vn_jahr = vn_d - 4715 - Int((7 + vn_monat) / 10)

vn_sekunde = Abs(pin_jldat - Int(pin_jldat)) * 86400
vn_stunde = vn_sekunde \ 3600
vn_sekunde = vn_sekunde - vn_stunde * 3600
vn_minute = vn_sekunde \ 60
vn_sekunde = Int(vn_sekunde - vn_minute * 60)

f_julidat2gregdat = DateSerial(vn_jahr, vn_monat, vn_tag) & " " & TimeSerial(vn_stunde, vn_minute, vn_sekunde)

End Function